Update nix flake

flake.lock

@@ -0,0 +1,26 @@
+{
+  "nodes": {
+    "nixpkgs": {
+      "locked": {
+        "lastModified": 1736061677,
+        "narHash": "sha256-DjkQPnkAfd7eB522PwnkGhOMuT9QVCZspDpJJYyOj60=",
+        "owner": "NixOS",
+        "repo": "nixpkgs",
+        "rev": "cbd8ec4de4469333c82ff40d057350c30e9f7d36",
+        "type": "github"
+      },
+      "original": {
+        "id": "nixpkgs",
+        "ref": "nixos-24.11",
+        "type": "indirect"
+      }
+    },
+    "root": {
+      "inputs": {
+        "nixpkgs": "nixpkgs"
+      }
+    }
+  },
+  "root": "root",
+  "version": 7
+}

flake.nix

@@ -0,0 +1,129 @@
+{
+  description = "Photo/video organization tool";
+
+  inputs.nixpkgs.url = "nixpkgs/nixos-24.11";
+
+  outputs = { self, nixpkgs }:
+    let
+      lastModifiedDate = self.lastModifiedDate or self.lastModified or "19700101";
+      version = "2.0.0";
+      supportedSystems = [ "x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin" ];
+      forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
+      nixpkgsFor = forAllSystems (system: import nixpkgs { inherit system; });
+    in
+    {
+      packages = forAllSystems (system:
+        let
+          pkgs = nixpkgsFor.${system};
+        in
+        {
+          photocatalog = pkgs.buildGoModule {
+            pname = "photocatalog";
+            inherit version;
+            src = ./.;
+            vendorHash = "sha256-dj11SRRoB8ZbkcQs75HPI0DpW4c5jzY0N8MD1wKpw+4=";
+          };
+        }
+      );
+
+      nixosModules.photocatalog = { config, lib, pkgs, ... }:
+        with lib;
+      {
+        options.photocatalog = {
+          enable = lib.mkEnableOption "Enable photocatalog";
+
+          syncs = mkOption {
+            default = {};
+            description = ''
+              Organization paths with its own params.
+            '';
+            example = {
+
+            };
+            type = types.attrsOf (types.submodule ({ name, ... }: {
+#              freeformType = settingsFormat.type;
+              options = {
+                source = mkOption {
+                  type = types.str;
+                  default = name;
+                  description = ''
+                    Source folder path.
+                  '';
+                };
+                target = mkOption {
+                  type = types.str;
+                  description = ''
+                    Target folder path.
+                  '';
+                };
+                overwrite = mkOption {
+                  type = types.bool;
+                  default = false;
+                  description = ''
+                    Overwrite files, existing in target.
+                  '';
+                };
+                watch = mkOption {
+                  type = types.bool;
+                  default = true;
+                  description = ''
+                    Watch for new files in source path.
+                  '';
+                };
+                skipFullSync = mkOption {
+                  type = types.bool;
+                  default = false;
+                  description = ''
+                    Do not make full sync.
+                  '';
+                };
+                mode = mkOption {
+                  type = types.str;
+                  default = "hardlink";
+                  description = ''
+                    Organization mode, one of [ hardlink symlink move copy ].
+                  '';
+                };
+              };
+            }));
+          };
+        };
+
+        config = lib.mkIf config.photocatalog.enable {
+          environment.systemPackages = [ self.packages.${pkgs.system}.photocatalog ];
+          systemd.user.services = lib.mapAttrs' (name: sync: nameValuePair
+            ("photocatalog${lib.replaceStrings ["/"] ["-"] sync.source}")
+            {
+                after = [ "local-fs.target" ];
+                path = [
+                  self.packages.${pkgs.system}.photocatalog
+                ];
+                wantedBy = [
+                  "default.target"
+                ];
+                preStart = if !sync.skipFullSync then ''
+                  mkdir -p ${sync.target}
+                  photocatalog -source ${sync.source} -target ${sync.target} -mode ${sync.mode}
+                '' else null;
+                script = "photocatalog -source ${sync.source} -target ${sync.target} -skip-full-sync -watch -mode ${sync.mode}";
+                serviceConfig = {
+                  Type="simple";
+                  Restart="no";
+                };
+            }
+          ) config.photocatalog.syncs;
+        };
+      };
+
+      devShells = forAllSystems (system:
+        let
+          pkgs = nixpkgsFor.${system};
+        in
+        {
+          default = pkgs.mkShell {
+            buildInputs = with pkgs; [ go gopls gotools go-tools ];
+          };
+        });
+      defaultPackage = forAllSystems (system: self.packages.${system}.photocatalog);
+    };
+}

internal/organizer/organizer.go

@@ -19,7 +19,7 @@ import (
 )
 
 const (
-	defaultDirMode  = 0o777
+	defaultDirMode  = 0o774
 	defaultFileMode = 0o644
 )
 

main.go

@@ -35,7 +35,10 @@ func main() {
 }
 
 func loadCfg() application.Config {
-	cfg := application.Config{}
+	cfg := application.Config{
+		DirMode:  0774,
+		FileMode: 0644,
+	}
 
 	flag.StringVar(&cfg.SourceDir, "source", "", "Source directory")
 	flag.StringVar(&cfg.TargetDir, "target", "", "Target directory")
@@ -67,6 +70,10 @@ func loadCfg() application.Config {
 	})
 
 	flag.Func("mode", "Organizing mode", func(s string) error {
+		if s == "" {
+			cfg.Mode = application.ModeHardlink
+		}
+
 		cfg.Mode = application.Mode(s)
 
 		if !slices.Contains(application.SupportedModes, cfg.Mode) {